Сжатие данных

[ivagor]

upkr удобно сравнивать с идеологически близким шринклером, он примерно в 2 раза быстрее шринклера, соответственно правее. На моем тестовом наборе (20 векторовских программ) upkr сжал немного лучше шринклера, но если говорить конкретно про тот график, то там надо брать и соответствующий тестовый набор (который мне не интересен применительно к вектору). Скорее всего upkr все же и на том тестовом наборе чуть выше, но это даже не принципиально при том выигрыше в скорости, размере распаковщиков и таблиц, который он демонстрирует. Еще можно сравнить циферки тут. Плюс еще возможность ограничивать дальность ссылок, что позволяет при необходимости распаковывать в круговой буфер (для шринклера нет такого упаковщика).
Кстати, если взять картинки upkrdemo в пиксельном, а не в битплановом представлении и сжать с ограничением для буфера 256 байт, то выигрыш >2 килобайт (это даже с учетом 256 байт). Т.е. можно уместить две полновысотные картинки шире 208 точек.
Ну и я все еще не против общения на ты.

[Advertiser]

[Eugene85]

nzeemin,
Если вы про UPKR, то точка будет (LDIR x 189; 2.29)

[Eugene85]

но для него нет упаковщика с возможностью ограничения длины смещений.

Как же нет, когда есть :)

[ivagor]

Сократил DeRIP на 7 байт и чуть ускорил. Изменил описание, т.к. новый RIP сам умеет переворачивать битовый поток.

[Pyk]

ivagor, а что с репозиторием на github?

[NEO SPECTRUMAN]

ivagor, а что с репозиторием на github?

Оо!
И такого опасного для ваших банковских щетов ivagor-а зашадов прибанили

- - - Добавлено - - -

ivagor, это ты не включил 2FA?

- - - Добавлено - - -

хотя те кто ужо давно не ходит в/на гитх00б еще вроде есть


или это ивагор там был просто раньше зареган?
а тем уйти в 404 еще не пришло время

[NEO SPECTRUMAN]

ivagor, так ты сам удолилсо или тя удолили?

[Improver]

ivagor, вопрос есть по распаковщику... Решил сделать упакованный вариант какой-нибудь игрушки, попалась MoonBugs (moonbugs.rom), упаковал её при помощи LZSA с ключами "-f1 -r" и дополнил таким распаковщиком на основе твоего unlzsa, когда-то имевшегося на гитхабе:

Исходники

	.ORG	100H
START:	DI
	LXI	SP,000F0H
	LXI	H,PAKPR		; откуда
	LXI	D, 0A000H	; куда
BEGIN:	MOV	A,M
	STAX	D
	INX	H
	INR	E
	JNZ	BEGIN
	INR	D
	MOV	A,D
	CPI	0FFH
	JC	BEGIN		; цикл до адреса FF00h
	LXI	D, START
	PUSH	D		; для запуска распакованного
	LXI	H, PDATA
	JMP	0A000H
PAKPR:	.db 0FFh
;
	.org 0A000H		; после компиляции удалить область от PAKPR до 0A000H и дописать в конец архив
;
;input: 	hl=compressed data start
;		de=uncompressed destination start
unlzsa1:
	mvi b,0
	jmp ReadToken
;
NoLiterals:
	xra m
	push d
	inx h
	mov e,m
	jm LongOffset
ShortOffset:
	mvi d,0FFh
	adi 3
	cpi 15+3
	jnc LongerMatch
CopyMatch:
	mov c,a
CopyMatch_UseC:
	inx h
	xthl
	xchg
	dad d
	mov a,m
	inx h
	stax d
	inx d
	dcx b
	mov a,m
	inx h
	stax d
	inx d
	dcx b
	dcx b
	inr c
BLOCKCOPY1:
	mov a,m
	stax d
	inx h
	inx d
	dcr c
	jnz BLOCKCOPY1
	xra a
	ora b
	jz $+7		; >>>
	dcr b
	jmp BLOCKCOPY1
	pop h		; <<<
ReadToken:
	mov a,m
	ani 70h
	jz NoLiterals 
	cpi 70h
	jz MoreLiterals
	rrc
	rrc
	rrc
	rrc
	mov c,a
	mov b,m
	inx h
	mov a,m		; <<<
	stax d
	inx h
	inx d
	dcr c
	jnz $-5		; >>>
	push d
	mov e,m
	mvi a,8Fh
	ana b
	mvi b,0
	jp ShortOffset
LongOffset:
	inx h
	mov d,m
	adi -128+3
	cpi 15+3
	jc CopyMatch
LongerMatch:
	inx h
	add m
	jnc CopyMatch
	mov b,a
	inx h
	mov c,m
	jnz CopyMatch_UseC
	inx h
	mov b,m
	mov a,b
	ora c
	jnz CopyMatch_UseC
	pop d
	ret		; >>>>>>>>>>>>>>>
;
MoreLiterals:		
	xra m
	push psw
	mvi a,7
	inx h
	add m
	jc ManyLiterals
CopyLiterals:
	mov c,a
CopyLiterals_UseC:
	inx h
	dcx b
	inr c
BLOCKCOPY2:
	mov a,m
	stax d
	inx h
	inx d
	dcr c
	jnz BLOCKCOPY2
	xra a
	ora b
	jz $+7		; >>>
	dcr b
	jmp BLOCKCOPY1
	pop psw		; <<<
	push d
	mov e,m
	jp ShortOffset
	jmp LongOffset
ManyLiterals:
	mov b,a
	inx h
	mov c,m
	jnz CopyLiterals_UseC
	inx h
	mov b,m
	jmp CopyLiterals_UseC
;
PDATA:	.END

[свернуть]

Начало, вроде, отрабатывает нормально, но при распаковке после адреса 3BC4h сыпет мусор в память. Что я там не так сделал, подскажи?
Собранный распаковщик с архивом игры, для тестов: moonbugp.rar

[ivagor]

Вероятно когда ты преобразовывал исходник для себя сделал одну неправильную замену. В конце цикла BLOCKCOPY2 должно быть jmp BLOCKCOPY2 вместо jmp BLOCKCOPY1

[Improver]

когда ты преобразовывал исходник для себя сделал одну неправильную замену

Спасибо, исправил. Эту подпрограмму я скопировал из РДС, и там та же ошибка, но, наверно, повезло -- в РДС она себя не проявила...